From 446c0feadf7ca4a3289a5a0c9e0bbe0e74801f12 Mon Sep 17 00:00:00 2001
From: Ralph Amissah <ralph.amissah@gmail.com>
Date: Sun, 4 Jun 2023 18:18:21 -0400
Subject: nix use overlays when convenient
---
nix-overlays/README | 153 ++++++++++++++++++++++++++++
nix-overlays/dmd/binary.nix | 72 +++++++++++++
nix-overlays/dmd/bootstrap.nix | 9 ++
nix-overlays/dmd/default.nix | 6 ++
nix-overlays/dmd/generic.nix | 219 ++++++++++++++++++++++++++++++++++++++++
nix-overlays/dtools/default.nix | 51 ++++++++++
nix-overlays/dub/default.nix | 83 +++++++++++++++
nix-overlays/ldc/binary.nix | 43 ++++++++
nix-overlays/ldc/bootstrap.nix | 11 ++
nix-overlays/ldc/default.nix | 4 +
nix-overlays/ldc/generic.nix | 137 +++++++++++++++++++++++++
11 files changed, 788 insertions(+)
create mode 100644 nix-overlays/README
create mode 100644 nix-overlays/dmd/binary.nix
create mode 100644 nix-overlays/dmd/bootstrap.nix
create mode 100644 nix-overlays/dmd/default.nix
create mode 100644 nix-overlays/dmd/generic.nix
create mode 100644 nix-overlays/dtools/default.nix
create mode 100644 nix-overlays/dub/default.nix
create mode 100644 nix-overlays/ldc/binary.nix
create mode 100644 nix-overlays/ldc/bootstrap.nix
create mode 100644 nix-overlays/ldc/default.nix
create mode 100644 nix-overlays/ldc/generic.nix
(limited to 'nix-overlays')
diff --git a/nix-overlays/README b/nix-overlays/README
new file mode 100644
index 0000000..3e40ec0
--- /dev/null
+++ b/nix-overlays/README
@@ -0,0 +1,153 @@
+-*- mode: org -*-
+#+TITLE: D related overlays
+#+DESCRIPTION: ldc, dub, dtools: dlang compiler build tool and tools
+#+FILETAGS: :dlang:build:tools:
+#+AUTHOR: Ralph Amissah
+#+EMAIL: [[mailto:ralph.amissah@gmail.com][ralph.amissah@gmail.com]]
+#+COPYRIGHT: Copyright (C) 2015 - 2023 Ralph Amissah
+#+LANGUAGE: en
+#+STARTUP: content hideblocks hidestars noindent entitiespretty
+#+OPTIONS: H:3 num:nil toc:t \n:nil @:t ::t |:t ^:nil _:nil -:t f:t *:t <:t
+#+PROPERTY: header-args :exports code
+#+PROPERTY: header-args+ :noweb yes
+#+PROPERTY: header-args+ :eval no
+#+PROPERTY: header-args+ :results no
+#+PROPERTY: header-args+ :cache no
+#+PROPERTY: header-args+ :padline no
+
+* README for D related overlays
+** dlang-nix-overlays
+
+Nix build overlays for building and testing more recent versions of the dlang
+compiler and build tools: ldc, dub and dtools, than exist in nixpkgs at the time
+of publishing, in some cases with additional fixes.
+
+nix overlays for (updates nixpkgs, more recent versions of):
+ - ldc ( 1.30.0 -> 1.33.0-beta1 )
+ - dub ( 1.23.0 -> 1.30.0 ) [for nix versions 1.31.0 ... 1.33.0 broken]
+ - dtools ( 2.095.1 -> 2.103.1 )
+
+ - dmd ( 2.100.2 -> 2.104.0 ) KO ✗
+ - gdc [not yet available]
+
+(updates nixpkgs circa 2023-05-12)
+
+dlang-nix-flakes.org --❯
+ .
+ └── nix-overlays
+ ├── dmd
+ │ ├── binary.nix
+ │ ├── bootstrap.nix
+ │ ├── default.nix
+ │ └── generic.nix
+ ├── dtools
+ │ └── default.nix
+ ├── dub
+ │ └── default.nix
+ ├── ldc
+ │ ├── binary.nix
+ │ ├── bootstrap.nix
+ │ ├── default.nix
+ │ └── generic.nix
+ └── README
+
+search nixpkgs here:
+
+- https://search.nixos.org/packages?channel=unstable&from=0&size=100&sort=relevance&query=
+
+** compilers
+*** ldc OK ✓ ( 1.30.0 -> 1.33.0-beta1 )
+
+- https://wiki.dlang.org/LDC
+
+- https://github.com/ldc-developers/ldc
+ - https://github.com/ldc-developers/ldc/releases
+ nix-prefetch-url --unpack https://github.com/ldc-developers/ldc/archive/refs/tags/v1.33.0-beta1.tar.gz
+ - https://github.com/ldc-developers/ldc/issues
+
+- version in nixpkgs:
+ - https://search.nixos.org/packages?channel=unstable&show=ldc&from=0&size=100&sort=relevance&type=packages&query=ldc
+
+*** dmd KO ✗ ( 2.100.2 -> 2.104.0 )
+
+- https://dlang.org/
+ - https://wiki.dlang.org/LDC
+
+- https://github.com/dlang/dmd
+ - https://github.com/dlang/dmd/tags
+ nix-prefetch-url --unpack https://github.com/dlang/dmd/archive/refs/tags/v2.104.0.tar.gz
+ - https://github.com/dlang/dmd/pulls
+
+- version in nixpkgs:
+ - https://search.nixos.org/packages?channel=unstable&show=dmd&from=0&size=100&sort=relevance&type=packages&query=dmd
+
+- dmd nixpkg modified and appears to build ok, but it appears my overlay does
+ not get things right REVIEW
+
+- dmd on nixos FAILS to build (my working projects), appears not to find parts
+ of itself
+
+*** gdc ( not provided yet with gcc12 in nixpkgs )
+
+not yet provided in nixpkgs with gcc12, no attempt made
+
+- https://wiki.dlang.org/GDC
+ - https://wiki.dlang.org/GDC_Development
+
+- https://github.com/D-Programming-GDC/gdc
+
+** build tool
+*** dub ( 1.23.0 -> 1.30.0 )
+
+- https://code.dlang.org/packages/dub
+
+- https://github.com/dlang/dub
+ - https://github.com/dlang/dub/releases
+ nix-prefetch-url --unpack https://github.com/dlang/dub/archive/refs/tags/v1.30.0.tar.gz
+ - https://github.com/dlang/dub/issues
+
+- version in nixpkgs:
+ - https://search.nixos.org/packages?channel=unstable&show=dub&from=0&size=100&sort=relevance&type=packages&query=dub
+
+- dub nixpkg overlay is updated and runs most dub tests correctly
+
+- dub from v1.31.0 FAILS to build packages with nix tools that previous version
+ of dub built (from v1.23.0 to v1.30.0 which is currently in nixpkgs); FAILURE
+ is from v1.31.0 through v1.32.1 (which is current at the time of this commit)
+
+** tools
+*** dtools OK ✓ ( 2.095.1 -> 2.103.1 )
+
+- https://code.dlang.org/packages/dtools
+
+- https://github.com/dlang/tools
+ - https://github.com/dlang/tools/tags
+ nix-prefetch --unpack https://github.com/dlang/tools/archive/refs/tags/v2.103.1.tar.gz
+ - https://github.com/dlang/tools/issues
+
+- version in nixpkgs
+ - https://search.nixos.org/packages?channel=unstable&show=dtools&from=0&size=100&sort=relevance&type=packages&query=dtools
+
+** nixpkgs
+
+It is possible to work directly against a local copy of nixpkgs. To do so you
+would clone nixpkgs and point to the local nixpkgs as your build source.
+
+git clone --depth=1 --branch master https://github.com/nixos/nixpkgs nixpkgs
+
+- ./nixpkgs/pkgs/development/compilers/ldc
+- ./nixpkgs/pkgs/development/compilers/dmd
+- ./nixpkgs/pkgs/development/tools/build-managers/dub
+- ./nixpkgs/pkgs/development/tools/dtools
+
+- ./nixpkgs/pkgs/development/compilers/gcc
+
+Note the overlays if copied to the nixpkgs path locations should work as they do
+in the overlay, with a pointer to the cloned nixpkgs as nixpkgs repository
+source. In fact the starting point for the overlays was to take verbatim what
+was in nixpkgs and then to update and fix where necessary those packages.
+
+It is possible to compare the changes made by the overlays here directly against
+what is currently available in nixpkgs.
+
+- https://search.nixos.org/packages?channel=unstable&size=100&sort=relevance&query=
diff --git a/nix-overlays/dmd/binary.nix b/nix-overlays/dmd/binary.nix
new file mode 100644
index 0000000..6a99d42
--- /dev/null
+++ b/nix-overlays/dmd/binary.nix
@@ -0,0 +1,72 @@
+{ lib, stdenv, fetchurl, curl, tzdata, autoPatchelfHook, fixDarwinDylibNames, glibc
+, version, hashes }:
+
+let
+ inherit (stdenv) hostPlatform;
+ OS = if hostPlatform.isDarwin then "osx" else hostPlatform.parsed.kernel.name;
+ MODEL = toString hostPlatform.parsed.cpu.bits;
+in stdenv.mkDerivation {
+ pname = "dmd-bootstrap";
+ inherit version;
+
+ src = fetchurl rec {
+ name = "dmd.${version}.${OS}.tar.xz";
+ url = "http://downloads.dlang.org/releases/2.x/${version}/${name}";
+ sha256 = hashes.${OS} or (throw "missing bootstrap sha256 for OS ${OS}");
+ };
+
+ dontConfigure = true;
+ dontBuild = true;
+
+ nativeBuildInputs = lib.optionals hostPlatform.isLinux [
+ autoPatchelfHook
+ ] ++ lib.optionals hostPlatform.isDarwin [
+ fixDarwinDylibNames
+ ];
+ propagatedBuildInputs = [
+ curl
+ tzdata
+ ] ++ lib.optionals hostPlatform.isLinux [
+ glibc
+ stdenv.cc.cc.libgcc
+ ];
+
+ installPhase = ''
+ runHook preInstall
+
+ mkdir -p $out
+
+ # try to copy model-specific binaries into bin first
+ mv ${OS}/bin${MODEL} $out/bin || true
+
+ mv src license.txt ${OS}/* $out/
+
+ # move man into place
+ mkdir -p $out/share
+ mv man $out/share/
+
+ # move docs into place
+ mkdir -p $out/share/doc
+ mv html/d $out/share/doc/
+
+ # fix paths in dmd.conf (one level less)
+ substituteInPlace $out/bin/dmd.conf --replace "/../../" "/../"
+
+ runHook postInstall
+ '';
+
+ # Stripping on Darwin started to break libphobos2.a
+ # Undefined symbols for architecture x86_64:
+ # "_rt_envvars_enabled", referenced from:
+ # __D2rt6config16rt_envvarsOptionFNbNiAyaMDFNbNiQkZQnZQq in libphobos2.a(config_99a_6c3.o)
+ dontStrip = hostPlatform.isDarwin;
+
+ meta = with lib; {
+ description = "Digital Mars D Compiler Package";
+ # As of 2.075 all sources and binaries use the boost license
+ license = licenses.boost;
+ maintainers = [ maintainers.lionello ];
+ homepage = "https://dlang.org/";
+ platforms = [ "x86_64-darwin" "i686-linux" "x86_64-linux" ];
+ };
+}
diff --git a/nix-overlays/dmd/bootstrap.nix b/nix-overlays/dmd/bootstrap.nix
new file mode 100644
index 0000000..16aa5ed
--- /dev/null
+++ b/nix-overlays/dmd/bootstrap.nix
@@ -0,0 +1,9 @@
+{ callPackage }:
+callPackage ./binary.nix {
+ version = "2.090.1";
+ hashes = {
+ # Get these from `nix-prefetch-url http://downloads.dlang.org/releases/2.x/2.090.1/dmd.2.090.1.linux.tar.xz` etc..
+ osx = "sha256-9HwGVO/8jfZ6aTiDIUi8w4C4Ukry0uUS8ACP3Ig8dmU=";
+ linux = "sha256-ByCrIA4Nt7i9YT0L19VXIL1IqIp+iObcZux407amZu4=";
+ };
+}
diff --git a/nix-overlays/dmd/default.nix b/nix-overlays/dmd/default.nix
new file mode 100644
index 0000000..7beb9e5
--- /dev/null
+++ b/nix-overlays/dmd/default.nix
@@ -0,0 +1,6 @@
+import ./generic.nix {
+ version = "2.104.0";
+ dmdSha256 = "sha256-yv+uW6cYAId2HK/YSPxsR9Xt0o3LWa97z8KyzjFik6s=";
+ #druntimeSha256 = "";
+ phobosSha256 = "sha256-cWp36Gd/lh3gy21bf9z0/RqzlJmf6ypmx72aMeakcec=";
+}
diff --git a/nix-overlays/dmd/generic.nix b/nix-overlays/dmd/generic.nix
new file mode 100644
index 0000000..e500385
--- /dev/null
+++ b/nix-overlays/dmd/generic.nix
@@ -0,0 +1,219 @@
+{ version
+, dmdSha256
+, phobosSha256
+}:
+
+{ stdenv
+, lib
+, fetchFromGitHub
+, makeWrapper
+, which
+, writeTextFile
+, curl
+, tzdata
+, gdb
+, callPackage
+, targetPackages
+, fetchpatch
+, bash
+, installShellFiles
+, git
+, unzip
+, HOST_DMD ? "${callPackage ./bootstrap.nix { }}/bin/dmd"
+}:
+
+let
+ dmdConfFile = writeTextFile {
+ name = "dmd.conf";
+ text = (lib.generators.toINI { } {
+ Environment = {
+ DFLAGS = ''-I@out@/include/dmd -L-L@out@/lib -fPIC ${lib.optionalString (!targetPackages.stdenv.cc.isClang) "-L--export-dynamic"}'';
+ };
+ });
+ };
+
+ bits = builtins.toString stdenv.hostPlatform.parsed.cpu.bits;
+ osname =
+ if stdenv.isDarwin then
+ "osx"
+ else
+ stdenv.hostPlatform.parsed.kernel.name;
+
+ pathToDmd = "\${NIX_BUILD_TOP}/dmd/generated/${osname}/release/${bits}/dmd";
+in
+
+stdenv.mkDerivation rec {
+ pname = "dmd";
+ inherit version;
+
+ enableParallelBuilding = true;
+
+ srcs = [
+ (fetchFromGitHub {
+ owner = "dlang";
+ repo = "dmd";
+ rev = "v${version}";
+ sha256 = dmdSha256;
+ name = "dmd";
+ })
+ (fetchFromGitHub {
+ owner = "dlang";
+ repo = "phobos";
+ rev = "v${version}";
+ sha256 = phobosSha256;
+ name = "phobos";
+ })
+ ];
+
+ sourceRoot = ".";
+
+ # https://issues.dlang.org/show_bug.cgi?id=19553
+ hardeningDisable = [ "fortify" ];
+
+ #patches = lib.optionals (lib.versionOlder version "2.088.0") [
+ # # Migrates D1-style operator overloads in DMD source, to allow building with
+ # # a newer DMD
+ # (fetchpatch {
+ # url = "https://github.com/dlang/dmd/commit/c4d33e5eb46c123761ac501e8c52f33850483a8a.patch";
+ # stripLen = 1;
+ # extraPrefix = "dmd/";
+ # sha256 = "sha256-N21mAPfaTo+zGCip4njejasraV5IsWVqlGR5eOdFZZE=";
+ # })
+ #] ++ lib.optionals (lib.versionOlder version "2.092.2") [
+ # # Fixes C++ tests that compiled on older C++ but not on the current one
+ # (fetchpatch {
+ # url = "https://github.com/dlang/druntime/commit/438990def7e377ca1f87b6d28246673bb38022ab.patch";
+ # stripLen = 1;
+ # extraPrefix = "druntime/";
+ # sha256 = "sha256-/pPKK7ZK9E/mBrxm2MZyBNhYExE8p9jz8JqBdZSE6uY=";
+ # })
+ #];
+
+ postPatch = ''
+ patchShebangs dmd/compiler/test/{runnable,fail_compilation,compilable,tools}{,/extra-files}/*.sh
+
+ rm dmd/compiler/test/runnable_cxx/cppa.d
+
+ # Grep'd string changed with gdb 12
+ # https://issues.dlang.org/show_bug.cgi?id=23198
+ substituteInPlace dmd/druntime/test/exceptions/Makefile \
+ --replace 'in D main (' 'in _Dmain ('
+
+ # We're using gnused on all platforms
+ substituteInPlace dmd/druntime/test/coverage/Makefile \
+ --replace 'freebsd osx' 'none'
+ ''
+
+ + lib.optionalString (lib.versionOlder version "2.091.0") ''
+ # This one has tested against a hardcoded year, then against a current year on
+ # and off again. It just isn't worth it to patch all the historical versions
+ # of it, so just remove it until the most recent change.
+ rm dmd/compiler/test/compilable/ddocYear.d
+ '' + lib.optionalString (lib.versionAtLeast version "2.089.0" && lib.versionOlder version "2.092.2") ''
+ rm dmd/compiler/test/dshell/test6952.d
+ '' + lib.optionalString (lib.versionAtLeast version "2.092.2") ''
+ substituteInPlace dmd/compiler/test/dshell/test6952.d --replace "/usr/bin/env bash" "${bash}/bin/bash"
+ ''
+
+ + lib.optionalString stdenv.isLinux ''
+ substituteInPlace phobos/std/socket.d --replace "assert(ih.addrList[0] == 0x7F_00_00_01);" ""
+ '' + lib.optionalString stdenv.isDarwin ''
+ substituteInPlace phobos/std/socket.d --replace "foreach (name; names)" "names = []; foreach (name; names)"
+ '';
+
+ nativeBuildInputs = [
+ makeWrapper
+ which
+ installShellFiles
+ ] ++ lib.optionals (lib.versionOlder version "2.088.0") [
+ git
+ ];
+
+ buildInputs = [
+ curl
+ tzdata
+ ];
+
+ nativeCheckInputs = [
+ gdb
+ ] ++ lib.optionals (lib.versionOlder version "2.089.0") [
+ unzip
+ ];
+
+ buildFlags = [
+ "BUILD=release"
+ "ENABLE_RELEASE=1"
+ "PIC=1"
+ ];
+
+ # Build and install are based on http://wiki.dlang.org/Building_DMD
+ buildPhase = ''
+ runHook preBuild
+
+ export buildJobs=$NIX_BUILD_CORES
+ if [ -z $enableParallelBuilding ]; then
+ buildJobs=1
+ fi
+
+ make -C dmd -f posix.mak $buildFlags -j$buildJobs HOST_DMD=${HOST_DMD}
+ echo ${tzdata}/share/zoneinfo/ > TZDatabaseDirFile
+ echo ${lib.getLib curl}/lib/libcurl${stdenv.hostPlatform.extensions.sharedLibrary} > LibcurlPathFile
+ make -C phobos -f posix.mak $buildFlags -j$buildJobs DMD=${pathToDmd} DFLAGS="-version=TZDatabaseDir -version=LibcurlPath -J$PWD"
+
+ runHook postBuild
+ '';
+
+ doCheck = true;
+
+ checkFlags = buildFlags;
+
+ # many tests are disbled because they are failing
+
+ # NOTE: Purity check is disabled for checkPhase because it doesn't fare well
+ # with the DMD linker. See https://github.com/NixOS/nixpkgs/issues/97420
+ checkPhase = ''
+ runHook preCheck
+
+ export checkJobs=$NIX_BUILD_CORES
+ if [ -z $enableParallelChecking ]; then
+ checkJobs=1
+ fi
+
+ NIX_ENFORCE_PURITY= \
+ make -C dmd/compiler/test $checkFlags CC=$CXX SHELL=$SHELL -j$checkJobs N=$checkJobs
+
+ NIX_ENFORCE_PURITY= \
+ make -C phobos -f posix.mak unittest $checkFlags -j$checkJobs DFLAGS="-version=TZDatabaseDir -version=LibcurlPath -J$PWD"
+
+ runHook postCheck
+ '';
+
+ installPhase = ''
+ runHook preInstall
+
+ install -Dm755 ${pathToDmd} $out/bin/dmd
+
+ installManPage dmd/docs/man/man*/*
+
+ mkdir $out/lib
+ cp phobos/generated/${osname}/release/${bits}/libphobos2.* $out/lib/
+
+ wrapProgram $out/bin/dmd \
+ --prefix PATH ":" "${targetPackages.stdenv.cc}/bin" \
+ --set-default CC "${targetPackages.stdenv.cc}/bin/cc"
+
+ substitute ${dmdConfFile} "$out/bin/dmd.conf" --subst-var out
+
+ runHook postInstall
+ '';
+
+ meta = with lib; {
+ description = "Official reference compiler for the D language";
+ homepage = "https://dlang.org/";
+ # Everything is now Boost licensed, even the backend.
+ # https://github.com/dlang/dmd/pull/6680
+ license = licenses.boost;
+ maintainers = with maintainers; [ ThomasMader lionello dukc ];
+ platforms = [ "x86_64-linux" "i686-linux" "x86_64-darwin" ];
+ };
+}
diff --git a/nix-overlays/dtools/default.nix b/nix-overlays/dtools/default.nix
new file mode 100644
index 0000000..d605e4d
--- /dev/null
+++ b/nix-overlays/dtools/default.nix
@@ -0,0 +1,51 @@
+{ stdenv, lib, fetchFromGitHub, fetchpatch, ldc, curl, gnumake42 }:
+
+stdenv.mkDerivation rec {
+ pname = "dtools";
+ version = "2.103.1";
+
+ src = fetchFromGitHub {
+ owner = "dlang";
+ repo = "tools";
+ rev = "v${version}";
+ sha256 = "sha256-XM4gUxcarQCOBR8W/o0iWAI54PyLDkH6CsDce22Cnu4=";
+ name = "dtools";
+ };
+
+ patches = [
+ (fetchpatch {
+ # part of https://github.com/dlang/tools/pull/441
+ url = "https://github.com/dlang/tools/commit/6c6a042d1b08e3ec1790bd07a7f69424625ee866.patch"; # Fix LDC arm64 build
+ sha256 = "sha256-x6EclTYN1Y5FG57KLhbBK0BZicSYcZoWO7MTVcP4T18=";
+ })
+ ];
+
+ nativeBuildInputs = [ ldc gnumake42 ]; # fails with make 4.4
+ buildInputs = [ curl ];
+
+ makeCmd = ''
+ make -f posix.mak all DMD_DIR=dmd DMD=${ldc.out}/bin/ldmd2 CC=${stdenv.cc}/bin/cc
+ '';
+
+ buildPhase = ''
+ $makeCmd
+ '';
+
+ doCheck = true;
+
+ checkPhase = ''
+ $makeCmd test_rdmd
+ '';
+
+ installPhase = ''
+ $makeCmd INSTALL_DIR=$out install
+ '';
+
+ meta = with lib; {
+ description = "Ancillary tools for the D programming language compiler";
+ homepage = "https://github.com/dlang/tools";
+ license = lib.licenses.boost;
+ maintainers = with maintainers; [ ThomasMader ];
+ platforms = lib.platforms.unix;
+ };
+}
diff --git a/nix-overlays/dub/default.nix b/nix-overlays/dub/default.nix
new file mode 100644
index 0000000..0ebc576
--- /dev/null
+++ b/nix-overlays/dub/default.nix
@@ -0,0 +1,83 @@
+{ lib, stdenv, fetchFromGitHub, curl, libevent, rsync, ldc, dcompiler ? ldc }:
+
+assert dcompiler != null;
+
+stdenv.mkDerivation rec {
+ pname = "dub";
+ version = "1.30.0";
+
+ enableParallelBuilding = true;
+
+ src = fetchFromGitHub {
+ owner = "dlang";
+ repo = "dub";
+ rev = "v${version}";
+ sha256 = "sha256-iVl7bjblvIxvrUX7Phq6h4AIAmZjNVkGYYFA1hhsE7c=";
+ };
+
+ #postUnpack = ''
+ # patchShebangs .
+ #'';
+
+ dubvar = "\\$DUB";
+ postPatch = ''
+ patchShebangs test
+
+ # Can be removed with https://github.com/dlang/dub/pull/1368
+ substituteInPlace test/fetchzip.sh \
+ --replace "dub remove" "\"${dubvar}\" remove"
+ '';
+
+ nativeBuildInputs = [ dcompiler libevent rsync ];
+ buildInputs = [ curl ];
+
+ buildPhase = ''
+ for DC_ in dmd ldmd2 gdmd; do
+ echo "... check for D compiler $DC_ ..."
+ export DC=$(type -P $DC_ || echo "")
+ if [ ! "$DC" == "" ]; then
+ break
+ fi
+ done
+ if [ "$DC" == "" ]; then
+ exit "Error: could not find D compiler"
+ fi
+ echo "$DC_ found and used as D compiler in buildPhase for $pname"
+ $DC ./build.d
+ ./build
+ '';
+
+ doCheck = !stdenv.isDarwin;
+
+ checkPhase = ''
+ export DUB=$NIX_BUILD_TOP/source/bin/dub
+ export PATH=$PATH:$NIX_BUILD_TOP/source/bin/
+ #export DC=${dcompiler.out}/bin/${if dcompiler.pname=="ldc" then "ldc2" else dcompiler.pname}
+ if [ "$DC" == "" ]; then
+ exit "Error: could not find D compiler"
+ fi
+ echo "DC out --> $DC"
+ export HOME=$TMP
+
+ rm -rf test/issue502-root-import
+ rm -rf test/dpath-variable
+ rm test/dpath-variable.sh
+ rm -rf test/git-dependency
+ rm -rf test/use-c-sources # added to build v1.33.0
+
+ ./test/run-unittest.sh
+ '';
+
+ installPhase = ''
+ mkdir -p $out/bin
+ cp bin/dub $out/bin
+ '';
+
+ meta = with lib; {
+ description = "Package and build manager for D applications and libraries";
+ homepage = "https://code.dlang.org/";
+ license = licenses.mit;
+ maintainers = with maintainers; [ ThomasMader ];
+ platforms = [ "x86_64-linux" "i686-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin" ];
+ };
+}
diff --git a/nix-overlays/ldc/binary.nix b/nix-overlays/ldc/binary.nix
new file mode 100644
index 0000000..dd4d51c
--- /dev/null
+++ b/nix-overlays/ldc/binary.nix
@@ -0,0 +1,43 @@
+{ lib, stdenv, fetchurl, curl, tzdata, autoPatchelfHook, fixDarwinDylibNames, libxml2
+, version, hashes }:
+
+let
+ inherit (stdenv) hostPlatform;
+ OS = if hostPlatform.isDarwin then "osx" else hostPlatform.parsed.kernel.name;
+ ARCH = if hostPlatform.isDarwin && hostPlatform.isAarch64 then "arm64" else hostPlatform.parsed.cpu.name;
+in stdenv.mkDerivation {
+ pname = "ldc-bootstrap";
+ inherit version;
+
+ src = fetchurl rec {
+ name = "ldc2-${version}-${OS}-${ARCH}.tar.xz";
+ url = "https://github.com/ldc-developers/ldc/releases/download/v${version}/${name}";
+ sha256 = hashes."${OS}-${ARCH}" or (throw "missing bootstrap sha256 for ${OS}-${ARCH}");
+ };
+
+ dontConfigure = true;
+ dontBuild = true;
+
+ nativeBuildInputs = lib.optionals hostPlatform.isLinux [
+ autoPatchelfHook
+ ] ++ lib.optional hostPlatform.isDarwin fixDarwinDylibNames;
+
+ buildInputs = lib.optionals stdenv.hostPlatform.isLinux [ libxml2 stdenv.cc.cc ];
+
+ propagatedBuildInputs = [ curl tzdata ];
+
+ installPhase = ''
+ mkdir -p $out
+
+ mv bin etc import lib LICENSE README $out/
+ '';
+
+ meta = with lib; {
+ description = "The LLVM-based D Compiler";
+ homepage = "https://github.com/ldc-developers/ldc";
+ # from https://github.com/ldc-developers/ldc/blob/master/LICENSE
+ license = with licenses; [ bsd3 boost mit ncsa gpl2Plus ];
+ maintainers = with maintainers; [ ThomasMader lionello ];
+ platforms = [ "x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin" ];
+ };
+}
diff --git a/nix-overlays/ldc/bootstrap.nix b/nix-overlays/ldc/bootstrap.nix
new file mode 100644
index 0000000..7724cbc
--- /dev/null
+++ b/nix-overlays/ldc/bootstrap.nix
@@ -0,0 +1,11 @@
+{ callPackage }:
+callPackage ./binary.nix {
+ version = "1.25.0";
+ hashes = {
+ # Get these from `nix-prefetch-url https://github.com/ldc-developers/ldc/releases/download/v1.19.0/ldc2-1.19.0-osx-x86_64.tar.xz` etc..
+ osx-x86_64 = "sha256-6iKnbS+oalLKmyS8qYD/wS21b7+O+VgsWG2iT4PrWPU=";
+ linux-x86_64 = "sha256-sfg47RdlsIpryc3iZvE17OtLweh3Zw6DeuNJYgpuH+o=";
+ linux-aarch64 = "sha256-UDZ43x4flSo+SfsPeE8juZO2Wtk2ZzwySk0ADHnvJBI=";
+ osx-arm64 = "sha256-O/x0vy0wwQFaDc4uWSeMhx+chJKqbQb6e5QNYf+7DCw=";
+ };
+}
diff --git a/nix-overlays/ldc/default.nix b/nix-overlays/ldc/default.nix
new file mode 100644
index 0000000..6fe637d
--- /dev/null
+++ b/nix-overlays/ldc/default.nix
@@ -0,0 +1,4 @@
+import ./generic.nix {
+ version = "1.33.0-beta1";
+ sha256 = "sha256-axyjDAWwxHmG2yPhL6P8cF6XvVvapfw0AWLjUrVRoug=";
+}
diff --git a/nix-overlays/ldc/generic.nix b/nix-overlays/ldc/generic.nix
new file mode 100644
index 0000000..f88f448
--- /dev/null
+++ b/nix-overlays/ldc/generic.nix
@@ -0,0 +1,137 @@
+{ version, sha256 }:
+{ lib, stdenv, fetchurl, cmake, ninja, llvm_14, curl, tzdata
+, libconfig, lit, gdb, unzip, darwin, bash
+, callPackage, makeWrapper, runCommand, targetPackages
+, ldcBootstrap ? callPackage ./bootstrap.nix { }
+}:
+
+let
+ pathConfig = runCommand "ldc-lib-paths" {} ''
+ mkdir $out
+ echo ${tzdata}/share/zoneinfo/ > $out/TZDatabaseDirFile
+ echo ${curl.out}/lib/libcurl${stdenv.hostPlatform.extensions.sharedLibrary} > $out/LibcurlPathFile
+ '';
+
+in
+
+stdenv.mkDerivation rec {
+ pname = "ldc";
+ inherit version;
+
+ src = fetchurl {
+ url = "https://github.com/ldc-developers/ldc/releases/download/v${version}/ldc-${version}-src.tar.gz";
+ inherit sha256;
+ };
+
+ # https://issues.dlang.org/show_bug.cgi?id=19553
+ hardeningDisable = [ "fortify" ];
+
+ postUnpack = ''
+ patchShebangs .
+ ''
+ + ''
+ rm ldc-${version}-src/tests/dmd/fail_compilation/mixin_gc.d
+ rm ldc-${version}-src/tests/dmd/runnable/xtest46_gc.d
+ rm ldc-${version}-src/tests/dmd/runnable/testptrref_gc.d
+
+ # test depends on current year
+ rm ldc-${version}-src/tests/dmd/compilable/ddocYear.d
+ ''
+ + lib.optionalString stdenv.hostPlatform.isDarwin ''
+ # https://github.com/NixOS/nixpkgs/issues/34817
+ rm -r ldc-${version}-src/tests/plugins/addFuncEntryCall
+ '';
+
+ postPatch = ''
+ # Setting SHELL=$SHELL when dmd testsuite is run doesn't work on Linux somehow
+ substituteInPlace tests/dmd/Makefile --replace "SHELL=/bin/bash" "SHELL=${bash}/bin/bash"
+ ''
+ + lib.optionalString stdenv.hostPlatform.isLinux ''
+ substituteInPlace runtime/phobos/std/socket.d --replace "assert(ih.addrList[0] == 0x7F_00_00_01);" ""
+ ''
+ + lib.optionalString stdenv.hostPlatform.isDarwin ''
+ substituteInPlace runtime/phobos/std/socket.d --replace "foreach (name; names)" "names = []; foreach (name; names)"
+ '';
+
+ nativeBuildInputs = [
+ cmake ldcBootstrap lit lit.python llvm_14.dev makeWrapper ninja unzip
+ ]
+ ++ lib.optionals stdenv.hostPlatform.isDarwin [
+ darwin.apple_sdk.frameworks.Foundation
+ ]
+ ++ lib.optionals (!stdenv.hostPlatform.isDarwin) [
+ # https://github.com/NixOS/nixpkgs/pull/36378#issuecomment-385034818
+ gdb
+ ];
+
+ buildInputs = [ curl tzdata ];
+
+ cmakeFlags = [
+ "-DD_FLAGS=-d-version=TZDatabaseDir;-d-version=LibcurlPath;-J${pathConfig}"
+ "-DCMAKE_BUILD_TYPE=Release"
+ ];
+
+ postConfigure = ''
+ export DMD=$PWD/bin/ldmd2
+ '';
+
+ makeFlags = [ "DMD=$DMD" ];
+
+ fixNames = lib.optionalString stdenv.hostPlatform.isDarwin ''
+ fixDarwinDylibNames() {
+ local flags=()
+
+ for fn in "$@"; do
+ flags+=(-change "$(basename "$fn")" "$fn")
+ done
+
+ for fn in "$@"; do
+ if [ -L "$fn" ]; then continue; fi
+ echo "$fn: fixing dylib"
+ install_name_tool -id "$fn" "''${flags[@]}" "$fn"
+ done
+ }
+
+ fixDarwinDylibNames $(find "$(pwd)/lib" -name "*.dylib")
+ export DYLD_LIBRARY_PATH=$(pwd)/lib
+ '';
+
+ # https://github.com/ldc-developers/ldc/issues/2497#issuecomment-459633746
+ additionalExceptions = lib.optionalString stdenv.hostPlatform.isDarwin
+ "|druntime-test-shared";
+
+ checkPhase = ''
+ # Build default lib test runners
+ ninja -j$NIX_BUILD_CORES all-test-runners
+
+ ${fixNames}
+
+ # Run dmd testsuite
+ export DMD_TESTSUITE_MAKE_ARGS="-j$NIX_BUILD_CORES DMD=$DMD"
+ ctest -V -R "dmd-testsuite"
+
+ # Build and run LDC D unittests.
+ ctest --output-on-failure -R "ldc2-unittest"
+
+ # Run LIT testsuite.
+ ctest -V -R "lit-tests"
+
+ # Run default lib unittests
+ ctest -j$NIX_BUILD_CORES --output-on-failure -E "ldc2-unittest|lit-tests|dmd-testsuite${additionalExceptions}"
+ '';
+
+ postInstall = ''
+ wrapProgram $out/bin/ldc2 \
+ --prefix PATH ":" "${targetPackages.stdenv.cc}/bin" \
+ --set-default CC "${targetPackages.stdenv.cc}/bin/cc"
+ '';
+
+ meta = with lib; {
+ description = "The LLVM-based D compiler";
+ homepage = "https://github.com/ldc-developers/ldc";
+ # from https://github.com/ldc-developers/ldc/blob/master/LICENSE
+ license = with licenses; [ bsd3 boost mit ncsa gpl2Plus ];
+ maintainers = with maintainers; [ ThomasMader lionello ];
+ platforms = [ "x86_64-linux" "i686-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin" ];
+ };
+}
--
cgit v1.2.3