summaryrefslogtreecommitdiffhomepage
diff options
context:
space:
mode:
Diffstat
-rw-r--r--.envrc6
-rw-r--r--.envrc-local9
-rw-r--r--.envrc-nix36
-rw-r--r--.gitignore41
-rw-r--r--README187
-rw-r--r--flake.lock61
-rw-r--r--flake.nix170
-rw-r--r--nix-overlays/dmd/binary.nix77
-rw-r--r--nix-overlays/dmd/bootstrap.nix9
-rw-r--r--nix-overlays/dmd/default.nix5
-rw-r--r--nix-overlays/dmd/generic.nix226
-rw-r--r--nix-overlays/dtools/default.nix51
-rw-r--r--nix-overlays/dub/default.nix86
-rw-r--r--nix-overlays/ldc/binary.nix43
-rw-r--r--nix-overlays/ldc/bootstrap.nix11
-rw-r--r--nix-overlays/ldc/default.nix4
-rw-r--r--nix-overlays/ldc/generic.nix136
-rw-r--r--nixDevEnv.sh3
-rwxr-xr-xshell.nix44
19 files changed, 1205 insertions, 0 deletions
diff --git a/.envrc b/.envrc
new file mode 100644
index 0000000..6ad5fe2
--- /dev/null
+++ b/.envrc
@@ -0,0 +1,6 @@
+if [ -f .envrc-local ]; then
+ source_env_if_exists .envrc-local || source .envrc-local
+fi
+if [ -f .envrc-nix ]; then
+ source_env_if_exists .envrc-nix || source .envrc-nix
+fi
diff --git a/.envrc-local b/.envrc-local
new file mode 100644
index 0000000..ce9bbb8
--- /dev/null
+++ b/.envrc-local
@@ -0,0 +1,9 @@
+#if [[ !( -f ./nix-flakes.org) && -f ../dlang-nix-flakes.org ]]; then
+# # for editing purpose link to the .org file that creates ./dlang-nix-flakes/ content
+# ln -s ../dlang-nix-flakes.org ./nix-flakes.org
+#fi
+if [[ ! -d ./.git ]]; then
+ git init
+ git add .
+fi
+#eval "$(nix print-dev-env)"
diff --git a/.envrc-nix b/.envrc-nix
new file mode 100644
index 0000000..f91e3f5
--- /dev/null
+++ b/.envrc-nix
@@ -0,0 +1,36 @@
+NIX_ENFORCE_PURITY=1
+# - https://github.com/nix-community/nix-direnv
+NixDirEnvVersion="3.0.4"
+NixDirEnvSHA="sha256-DzlYZ33mWF/Gs8DDeyjr8mnVmQGx7ASYqA5WlxwvBG4="
+if ! has nix_direnv_version || ! nix_direnv_version ${NixDirEnvVersion}; then
+ source_url "https://raw.githubusercontent.com/nix-community/nix-direnv/${NixDirEnvVersion}/direnvrc" "${NixDirEnvSHA}"
+fi
+watch_file flake.lock
+watch_file flake.nix
+watch_file shell.nix
+watch_file makefile
+watch_file nixDevEnv.sh
+watch_file .envrc-local
+watch_file .envrc-nix
+nix flake update
+nix flake check
+nix flake show
+echo ""
+PATH_add result/bin
+use flake .
+#use flake .#default
+echo '
+- consider running:
+ ❯❯ nix flake show
+ ❯❯ nix flake update && nix flake check && nix flake show
+ ❯❯ nix flake update && nix flake check --show-trace && nix flake show && nix develop ".#devShell" -c $SHELL
+
+- for a dev shell:
+ ❯❯ nix develop
+ ❯❯ nix develop -c $SHELL
+ ❯❯ nix develop ".#dsh-overlay-ldc" --print-build-logs
+
+- to build project:
+ ❯❯ nix build --print-build-logs
+ ❯❯ nix build ".#" --print-build-logs
+'
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 0000000..b177cc1
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,41 @@
+# git ls-files --others --exclude-from=.git/info/exclude
+# git check-ignore -v flake.lock
+# git clean -ix
+# find . -name "*_" | xargs rm -rf
+# find . -name "*.o" | xargs rm -rf
+*
+!.gitignore
+!nixDevEnv.sh
+!.envrc
+!.envrc-local
+!.envrc-nix
+!flake.nix
+!flake.lock
+!nix-overlays
+!nix-overlays/**
+!shell.nix
+!makefile
+!justfile
+!README
+!*.nix
+!*.json
+!*.org
+!*.sh
+!*.d
+!*.txt
+!src
+!src/**
+!views
+
+# EXCLUDED Files & directories - ensure excluded
+.dub/**
+tmp/**
+*_.org
+*_.nix
+*_.d
+*_.txt
+*_
+*.swp
+*~
+*.\#*
+\#*
diff --git a/README b/README
new file mode 100644
index 0000000..35c600e
--- /dev/null
+++ b/README
@@ -0,0 +1,187 @@
+-*- mode: org -*-
+#+TITLE: D related overlays
+#+DESCRIPTION: ldc, dub, dtools: dlang compiler build tool and tools
+#+FILETAGS: :dlang:build:tools:
+#+AUTHOR: Ralph Amissah
+#+EMAIL: [[mailto:ralph.amissah@gmail.com][ralph.amissah@gmail.com]]
+#+COPYRIGHT: Copyright (C) 2022 - 2024 Ralph Amissah
+#+LANGUAGE: en
+#+STARTUP: content hideblocks hidestars noindent entitiespretty
+
+* README for D related dev shells with overlays
+** in emacs write (tangle) this (org) file for its output
+
+This org file: "dlang-nix-flakes.org" when using emacs and saved (tangling output)
+it creates and writes output to the subdirectory path:
+
+ ./dlang-nix-flakes
+
+and writes output there, this is to prevent accidentally writing over anything
+in the directory in which the dlang-nix-flakes.org file happens to be saved.
+
+./dlang-nix-flakes becomes your nix flake work directory.
+
+** dlang-nix-flakes.org
+
+the file dlang-nix-flakes.org contains nix related files for producing more
+recent versions of the dlang compiler and build tools: ldc, dub and dtools, than
+exist in nixpkgs at the time of publishing, in some cases with additional fixes.
+
+.envrc files
+
+nix control files
+ - default.nix
+ - shell.nix
+ - flake.nix
+
+nix overlays for (updates nixpkgs, more recent versions of):
+ - ldc ( 1.30.0 -> 1.37.0 )
+ - dub ( 1.23.0 -> 1.36.0 ) [for nix versions 1.31.0 ... 1.33.0 broken]
+ - dtools ( 2.095.1 -> 2.103.1 )
+
+ - dmd ( 2.100.2 -> 2.106.1 ) KO ✗
+ - gdc [not yet available]
+
+(updates nixpkgs circa 2023-05-12)
+
+dlang-nix-flakes.org --❯
+ .
+ └── dlang-nix-flakes
+ ├── #default.nix
+ ├── flake.lock
+ ├── flake.nix
+ ├── README
+ ├── shell.nix
+ └── nix-overlays
+    ├── dmd [not working]
+    │   ├── binary.nix
+    │   ├── bootstrap.nix
+    │   ├── default.nix
+    │   └── generic.nix
+    ├── dtools
+    │   └── default.nix
+    ├── dub
+    │   └── default.nix
+    └── ldc
+    ├── binary.nix
+    ├── bootstrap.nix
+    ├── default.nix
+    └── generic.nix
+
+search nixpkgs here:
+
+- https://search.nixos.org/packages?channel=unstable&from=0&size=100&sort=relevance&query=
+
+** compilers
+*** ldc OK ✓ ( 1.30.0 -> 1.37.0 )
+
+- https://wiki.dlang.org/LDC
+
+- https://github.com/ldc-developers/ldc
+ - https://github.com/ldc-developers/ldc/releases
+ nix-prefetch-url --unpack https://github.com/ldc-developers/ldc/archive/refs/tags/v1.37.0.tar.gz
+ - https://github.com/ldc-developers/ldc/issues
+
+- version in nixpkgs:
+ - https://search.nixos.org/packages?channel=unstable&show=ldc&from=0&size=100&sort=relevance&type=packages&query=ldc
+
+*** dmd KO ✗ ( 2.100.2 -> 2.106.1 )
+
+- https://dlang.org/
+ - https://wiki.dlang.org/LDC
+
+- https://github.com/dlang/dmd
+ - https://github.com/dlang/dmd/tags
+ nix-prefetch-url --unpack https://github.com/dlang/dmd/archive/refs/tags/v2.106.1.tar.gz
+ - https://github.com/dlang/dmd/pulls
+
+- version in nixpkgs:
+ - https://search.nixos.org/packages?channel=unstable&show=dmd&from=0&size=100&sort=relevance&type=packages&query=dmd
+
+- dmd nixpkg modified and appears to build ok, but it appears my overlay does
+ not get things right REVIEW
+
+- dmd on nixos FAILS to build (my working projects), appears not to find parts
+ of itself
+
+*** gdc ( not provided yet with gcc12 in nixpkgs )
+
+not yet provided in nixpkgs with gcc12, no attempt made
+
+- https://wiki.dlang.org/GDC
+ - https://wiki.dlang.org/GDC_Development
+
+- https://github.com/D-Programming-GDC/gdc
+
+** build tool
+*** dub ( 1.23.0 -> 1.36.0 )
+
+- https://code.dlang.org/packages/dub
+
+- https://github.com/dlang/dub
+ - https://github.com/dlang/dub/releases
+ nix-prefetch-url --unpack https://github.com/dlang/dub/archive/refs/tags/v1.36.0.tar.gz
+ - https://github.com/dlang/dub/issues
+
+- version in nixpkgs:
+ - https://search.nixos.org/packages?channel=unstable&show=dub&from=0&size=100&sort=relevance&type=packages&query=dub
+
+- dub nixpkg overlay is updated and runs most dub tests correctly
+
+- dub OK ✓ ( 1.30.0 -> 1.36.0 )
+
+ from v1.31.0 requires seeting of pwd in buildPhase else fails to build
+ packages with nix tools that previous version of dub built;
+
+** tools
+*** dtools OK ✓ ( 2.095.1 -> 2.103.1 )
+
+- https://code.dlang.org/packages/dtools
+
+- https://github.com/dlang/tools
+ - https://github.com/dlang/tools/tags
+ nix-prefetch --unpack https://github.com/dlang/tools/archive/refs/tags/v2.103.1.tar.gz
+ - https://github.com/dlang/tools/issues
+
+- version in nixpkgs
+ - https://search.nixos.org/packages?channel=unstable&show=dtools&from=0&size=100&sort=relevance&type=packages&query=dtools
+
+** nixpkgs
+
+It is possible to work directly against a local copy of nixpkgs. To do so you
+would clone nixpkgs and point to the local nixpkgs as your build source.
+
+git clone --depth=1 --branch master https://github.com/nixos/nixpkgs nixpkgs
+
+- ./nixpkgs/pkgs/development/compilers/ldc
+- ./nixpkgs/pkgs/development/compilers/dmd
+- ./nixpkgs/pkgs/development/tools/build-managers/dub
+- ./nixpkgs/pkgs/development/tools/dtools
+
+- ./nixpkgs/pkgs/development/compilers/gcc
+
+Note the overlays if copied to the nixpkgs path locations should work as they do
+in the overlay, with a pointer to the cloned nixpkgs as nixpkgs repository
+source. In fact the starting point for the overlays was to take verbatim what
+was in nixpkgs and then to update and fix where necessary those packages.
+
+It is possible to compare the changes made by the overlays here directly against
+what is currently available in nixpkgs.
+
+- https://search.nixos.org/packages?channel=unstable&size=100&sort=relevance&query=
+
+nix flake update && nix flake check --show-trace && nix flake info && echo "" && nix flake show
+ │
+ ├───devShells
+ │ └───x86_64-linux
+ │ ├───default: development environment 'nix-shell'
+ │ ├───dsh-nixpkgs-ldc-dub: development environment 'nixpkgs---ldc---dub'
+ │ ├───dsh-overlay-dmd-dub: development environment 'overlay---dmd-2.104.0---dub-1.30.0---broken'
+ │ ├───dsh-overlay-dtest-tilix: development environment 'overlay---ldc-1.32.2---dub-1.30.0---tilix---gtkd'
+ │ ├───dsh-overlay-dtools: development environment 'overlay---ldc-1.32.2---dub-1.30.0---dtools-2.103.1'
+ │ └───dsh-overlay-ldc-dub: development environment 'overlay---ldc-1.32.2---dub-1.30.0'
+ └───packages
+ └───x86_64-linux
+ ├───check-local-dir-build: package 'dummy-0.1.0'
+ ├───check-tilix: package 'tilix-1.9.5'
+ └───default: package 'tilix-1.9.5'
diff --git a/flake.lock b/flake.lock
new file mode 100644
index 0000000..8fd40d5
--- /dev/null
+++ b/flake.lock
@@ -0,0 +1,61 @@
+{
+ "nodes": {
+ "flake-utils": {
+ "inputs": {
+ "systems": "systems"
+ },
+ "locked": {
+ "lastModified": 1710146030,
+ "narHash": "sha256-SZ5L6eA7HJ/nmkzGG7/ISclqe6oZdOZTNoesiInkXPQ=",
+ "owner": "numtide",
+ "repo": "flake-utils",
+ "rev": "b1d9ab70662946ef0850d488da1c9019f3a9752a",
+ "type": "github"
+ },
+ "original": {
+ "owner": "numtide",
+ "repo": "flake-utils",
+ "type": "github"
+ }
+ },
+ "nixpkgs": {
+ "locked": {
+ "lastModified": 1713805509,
+ "narHash": "sha256-YgSEan4CcrjivCNO5ZNzhg7/8ViLkZ4CB/GrGBVSudo=",
+ "owner": "NixOS",
+ "repo": "nixpkgs",
+ "rev": "1e1dc66fe68972a76679644a5577828b6a7e8be4",
+ "type": "github"
+ },
+ "original": {
+ "owner": "NixOS",
+ "ref": "nixpkgs-unstable",
+ "repo": "nixpkgs",
+ "type": "github"
+ }
+ },
+ "root": {
+ "inputs": {
+ "flake-utils": "flake-utils",
+ "nixpkgs": "nixpkgs"
+ }
+ },
+ "systems": {
+ "locked": {
+ "lastModified": 1681028828,
+ "narHash": "sha256-Vy1rq5AaRuLzOxct8nz4T6wlgyUR7zLU309k9mBC768=",
+ "owner": "nix-systems",
+ "repo": "default",
+ "rev": "da67096a3b9bf56a91d16901293e51ba5b49a27e",
+ "type": "github"
+ },
+ "original": {
+ "owner": "nix-systems",
+ "repo": "default",
+ "type": "github"
+ }
+ }
+ },
+ "root": "root",
+ "version": 7
+}
diff --git a/flake.nix b/flake.nix
new file mode 100644
index 0000000..a085a14
--- /dev/null
+++ b/flake.nix
@@ -0,0 +1,170 @@
+{
+ description = "build dummy D package using dub build tool";
+ inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+ inputs.flake-utils.url = "github:numtide/flake-utils";
+ outputs = {
+ self,
+ nixpkgs,
+ flake-utils,
+ } @ inputs: let
+ pname = "dummy";
+ version = "0.1.0";
+ shell = ./shell.nix;
+ devEnv = ./nixDevEnv.sh; # ./.envrc;
+ supportedSystems = ["x86_64-linux"]; # [ "x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin" ];
+ forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
+ nixpkgsFor = forAllSystems (system: import nixpkgs {inherit system;});
+ checkPhase = ''
+ runHook preCheck
+ #dub test --combined --skip-registry=all
+ runHook postCheck
+ '';
+ localOverlay = (final: prev: {
+ ldc = prev.callPackage ./nix-overlays/ldc { }; # -> ok 1.37.0
+ dmd = prev.callPackage ./nix-overlays/dmd { }; # -> ok 2.106.1
+ dub = prev.callPackage ./nix-overlays/dub { }; # -> ? 1.36.0
+ dtools = prev.callPackage ./nix-overlays/dtools { }; # -> ok 2.103.1
+ #gdc = prev.callPackage ./nix-overlays/gdc { }; # empty
+ });
+ pkgsForSystem = system: import nixpkgs {
+ overlays = [
+ localOverlay
+ ];
+ inherit system;
+ };
+ installPhase = ''
+ runHook preInstall
+ mkdir -p $out/bin
+ install -m755 ./bin/dummy $out/bin/dummy
+ runHook postInstall
+ '';
+ postInstall = ''
+ echo `ls -la $out/bin/dummy`
+ $out/bin/dummy -v
+ '';
+ in {
+ packages = forAllSystems (system: let
+ pkgs-ovl = pkgsForSystem system;
+ pkgs-nix = nixpkgsFor.${system};
+ in
+ with pkgs-ovl; {
+ default = tilix;
+ check-tilix = tilix;
+ check-local-dir-build = stdenv.mkDerivation {
+ inherit pname;
+ inherit version;
+ meta.mainProgram = "dummy";
+ executable = true;
+ src = self;
+ inherit shell;
+ inherit devEnv;
+ buildInputs = [sqlite];
+ nativeBuildInputs = [dub ldc gnumake]; # [ dub dmd ]; [ dub ldc ]; [ dub gdc ];
+ buildPhase = ''
+ runHook preBuild
+ for DC_ in dmd ldmd2 ldc2 gdc gdmd; do
+ echo "- check for D compiler $DC_"
+ DC=$(type -P $DC_ || echo "")
+ if [ ! "$DC" == "" ]; then break; fi
+ done
+ if [ "$DC" == "" ]; then exit "Error: could not find D compiler"; fi
+ echo "$DC_ used as D compiler to build $pname"
+ dub build --cache=local --compiler=$DC --build=$DC_ --combined --skip-registry=all
+ runHook postBuild
+ '';
+ inherit checkPhase;
+ inherit installPhase;
+ inherit postInstall;
+ };
+ });
+ devShells = forAllSystems (system: let
+ pkgs-ovl = pkgsForSystem system;
+ pkgs-nix = nixpkgsFor.${system};
+ shellHook = ''
+ '';
+ in
+ with pkgs-ovl; {
+ dsh-overlay-dtools = mkShell {
+ name = "overlay - ldc-1.37.0 - dub-1.36.0 - dtools-2.103.1";
+ inherit shell;
+ inherit devEnv;
+ packages = [
+ gnumake
+ ldc
+ dub
+ dtools
+ ];
+ inherit shellHook;
+ };
+ dsh-overlay-ldc-dub = mkShell {
+ name = "overlay - ldc-1.37.0 - dub-1.36.0";
+ inherit shell;
+ inherit devEnv;
+ packages = [
+ gnumake
+ ldc
+ dub
+ ];
+ inherit shellHook;
+ };
+ dsh-overlay-dmd-dub = mkShell {
+ name = "overlay - dmd-2.106.1 - dub-1.36.0 - broken";
+ inherit shell;
+ inherit devEnv;
+ packages = [
+ gnumake
+ dmd
+ dub
+ ];
+ inherit shellHook;
+ };
+ dsh-overlay-dtest-tilix = mkShell {
+ name = "overlay - ldc-1.37.0 - dub-1.36.0 - tilix - gtkd";
+ inherit shell;
+ inherit devEnv;
+ packages = [
+ gnumake
+ ldc
+ gtkd
+ tilix
+ dub
+ ];
+ inherit shellHook;
+ };
+ #dsh-overlay-gdc = mkShell {
+ # name = "dub + gdc dev shell";
+ # inherit shell;
+ # inherit devEnv;
+ # packages = [
+ # gnumake
+ # gdc
+ # dub
+ # ];
+ # inherit shellHook;
+ #};
+ dsh-nixpkgs-ldc-dub = mkShell {
+ name = "nixpkgs - ldc - dub";
+ inherit shell;
+ inherit devEnv;
+ packages = with pkgs-nix; [
+ ldc
+ dub
+ gnumake
+ ];
+ inherit shellHook;
+ };
+ dsh-nixpkgs-dmd-dub = mkShell {
+ name = "nixpkgs - ldc - dub";
+ inherit shell;
+ inherit devEnv;
+ packages = with pkgs-nix; [
+ dmd
+ dub
+ gnumake
+ ];
+ inherit shellHook;
+ };
+ default = import ./shell.nix {inherit pkgs-nix;};
+ });
+ };
+}
diff --git a/nix-overlays/dmd/binary.nix b/nix-overlays/dmd/binary.nix
new file mode 100644
index 0000000..3a5d6b7
--- /dev/null
+++ b/nix-overlays/dmd/binary.nix
@@ -0,0 +1,77 @@
+{ lib, stdenv, fetchurl, curl, tzdata, autoPatchelfHook, fixDarwinDylibNames, glibc
+, version, hashes }:
+
+let
+ inherit (stdenv) hostPlatform;
+ OS = if hostPlatform.isDarwin then "osx" else hostPlatform.parsed.kernel.name;
+ MODEL = toString hostPlatform.parsed.cpu.bits;
+in
+
+# On linux pargets like `pkgsLLVM.dmd` `cc` does not expose `libgcc`
+# and can't build `dmd`.
+assert hostPlatform.isLinux -> (stdenv.cc.cc ? libgcc);
+stdenv.mkDerivation {
+ pname = "dmd-bootstrap";
+ inherit version;
+
+ src = fetchurl rec {
+ name = "dmd.${version}.${OS}.tar.xz";
+ url = "http://downloads.dlang.org/releases/2.x/${version}/${name}";
+ sha256 = hashes.${OS} or (throw "missing bootstrap sha256 for OS ${OS}");
+ };
+
+ dontConfigure = true;
+ dontBuild = true;
+
+ nativeBuildInputs = lib.optionals hostPlatform.isLinux [
+ autoPatchelfHook
+ ] ++ lib.optionals hostPlatform.isDarwin [
+ fixDarwinDylibNames
+ ];
+ propagatedBuildInputs = [
+ curl
+ tzdata
+ ] ++ lib.optionals hostPlatform.isLinux [
+ glibc
+ stdenv.cc.cc.libgcc
+ ];
+
+ installPhase = ''
+ runHook preInstall
+
+ mkdir -p $out
+
+ # try to copy model-specific binaries into bin first
+ mv ${OS}/bin${MODEL} $out/bin || true
+
+ mv src license.txt ${OS}/* $out/
+
+ # move man into place
+ mkdir -p $out/share
+ mv man $out/share/
+
+ # move docs into place
+ mkdir -p $out/share/doc
+ mv html/d $out/share/doc/
+
+ # fix paths in dmd.conf (one level less)
+ substituteInPlace $out/bin/dmd.conf --replace "/../../" "/../"
+
+ runHook postInstall
+ '';
+
+ # Stripping on Darwin started to break libphobos2.a
+ # Undefined symbols for architecture x86_64:
+ # "_rt_envvars_enabled", referenced from:
+ # __D2rt6config16rt_envvarsOptionFNbNiAyaMDFNbNiQkZQnZQq in libphobos2.a(config_99a_6c3.o)
+ dontStrip = hostPlatform.isDarwin;
+
+ meta = with lib; {
+ description = "Digital Mars D Compiler Package";
+ # As of 2.075 all sources and binaries use the boost license
+ license = licenses.boost;
+ maintainers = [ maintainers.lionello ];
+ homepage = "https://dlang.org/";
+ platforms = [ "x86_64-darwin" "i686-linux" "x86_64-linux" ];
+ };
+}
diff --git a/nix-overlays/dmd/bootstrap.nix b/nix-overlays/dmd/bootstrap.nix
new file mode 100644
index 0000000..16aa5ed
--- /dev/null
+++ b/nix-overlays/dmd/bootstrap.nix
@@ -0,0 +1,9 @@
+{ callPackage }:
+callPackage ./binary.nix {
+ version = "2.090.1";
+ hashes = {
+ # Get these from `nix-prefetch-url http://downloads.dlang.org/releases/2.x/2.090.1/dmd.2.090.1.linux.tar.xz` etc..
+ osx = "sha256-9HwGVO/8jfZ6aTiDIUi8w4C4Ukry0uUS8ACP3Ig8dmU=";
+ linux = "sha256-ByCrIA4Nt7i9YT0L19VXIL1IqIp+iObcZux407amZu4=";
+ };
+}
diff --git a/nix-overlays/dmd/default.nix b/nix-overlays/dmd/default.nix
new file mode 100644
index 0000000..bdc9faf
--- /dev/null
+++ b/nix-overlays/dmd/default.nix
@@ -0,0 +1,5 @@
+import ./generic.nix {
+ version = "2.106.1";
+ dmdSha256 = "sha256-vjYa/Pxrz7J2htXT+fa+xaeen/Vxne++lELbHTSXBK8=";
+ phobosSha256 = "sha256-yRL9ub3u4mREG9PVxBvgQ/LDXD57RadPTZ2h08qyh/s=";
+}
diff --git a/nix-overlays/dmd/generic.nix b/nix-overlays/dmd/generic.nix
new file mode 100644
index 0000000..a2a1b8a
--- /dev/null
+++ b/nix-overlays/dmd/generic.nix
@@ -0,0 +1,226 @@
+{ version
+, dmdSha256
+, phobosSha256
+}:
+
+{ stdenv
+, lib
+, fetchFromGitHub
+, removeReferencesTo
+, makeWrapper
+, which
+, writeTextFile
+, curl
+, tzdata
+, gdb
+#, Foundation
+, callPackage
+, targetPackages
+, fetchpatch
+, bash
+, installShellFiles
+, git
+, unzip
+, dmdBootstrap ? callPackage ./bootstrap.nix { }
+, dmd_bin ? "${dmdBootstrap}/bin"
+}:
+
+let
+ dmdConfFile = writeTextFile {
+ name = "dmd.conf";
+ text = (lib.generators.toINI { } {
+ Environment = {
+ DFLAGS = ''-I@out@/include/dmd -L-L@out@/lib -fPIC ${lib.optionalString (!targetPackages.stdenv.cc.isClang) "-L--export-dynamic"}'';
+ };
+ });
+ };
+
+ bits = builtins.toString stdenv.hostPlatform.parsed.cpu.bits;
+ osname =
+ if stdenv.isDarwin then
+ "osx"
+ else
+ stdenv.hostPlatform.parsed.kernel.name;
+
+ pathToDmd = "\${NIX_BUILD_TOP}/dmd/generated/${osname}/release/${bits}/dmd";
+in
+
+stdenv.mkDerivation rec {
+ pname = "dmd";
+ inherit version;
+
+ enableParallelBuilding = true;
+
+ srcs = [
+ (fetchFromGitHub {
+ owner = "dlang";
+ repo = "dmd";
+ rev = "v${version}";
+ sha256 = dmdSha256;
+ name = "dmd";
+ })
+ (fetchFromGitHub {
+ owner = "dlang";
+ repo = "phobos";
+ rev = "v${version}";
+ sha256 = phobosSha256;
+ name = "phobos";
+ })
+ ];
+
+ sourceRoot = ".";
+
+ # https://issues.dlang.org/show_bug.cgi?id=19553
+ hardeningDisable = [ "fortify" ];
+
+ patches = lib.optionals (lib.versionOlder version "2.088.0") [
+ # Migrates D1-style operator overloads in DMD source, to allow building with
+ # a newer DMD
+ (fetchpatch {
+ url = "https://github.com/dlang/dmd/commit/c4d33e5eb46c123761ac501e8c52f33850483a8a.patch";
+ stripLen = 1;
+ extraPrefix = "dmd/";
+ sha256 = "sha256-N21mAPfaTo+zGCip4njejasraV5IsWVqlGR5eOdFZZE=";
+ })
+ ];
+
+ postPatch = ''
+ patchShebangs dmd/compiler/test/{runnable,fail_compilation,compilable,tools}{,/extra-files}/*.sh
+
+ rm dmd/compiler/test/runnable/gdb1.d
+ rm dmd/compiler/test/runnable/gdb10311.d
+ rm dmd/compiler/test/runnable/gdb14225.d
+ rm dmd/compiler/test/runnable/gdb14276.d
+ rm dmd/compiler/test/runnable/gdb14313.d
+ rm dmd/compiler/test/runnable/gdb14330.d
+ rm dmd/compiler/test/runnable/gdb15729.sh
+ rm dmd/compiler/test/runnable/gdb4149.d
+ rm dmd/compiler/test/runnable/gdb4181.d
+ rm dmd/compiler/test/compilable/ddocYear.d
+
+ # Disable tests that rely on objdump whitespace until fixed upstream:
+ # https://issues.dlang.org/show_bug.cgi?id=23317
+ rm dmd/compiler/test/runnable/cdvecfill.sh
+ rm dmd/compiler/test/compilable/cdcmp.d
+ ''
+
+ + lib.optionalString (lib.versionAtLeast version "2.089.0" && lib.versionOlder version "2.092.2") ''
+ rm dmd/compiler/test/dshell/test6952.d
+ '' + lib.optionalString (lib.versionAtLeast version "2.092.2") ''
+ substituteInPlace dmd/compiler/test/dshell/test6952.d --replace "/usr/bin/env bash" "${bash}/bin/bash"
+ ''
+
+ + lib.optionalString stdenv.isLinux ''
+ substituteInPlace phobos/std/socket.d --replace "assert(ih.addrList[0] == 0x7F_00_00_01);" ""
+ '' + lib.optionalString stdenv.isDarwin ''
+ substituteInPlace phobos/std/socket.d --replace "foreach (name; names)" "names = []; foreach (name; names)"
+ '';
+
+ nativeBuildInputs = [
+ makeWrapper
+ which
+ installShellFiles
+ ] ++ lib.optionals (lib.versionOlder version "2.088.0") [
+ git
+ ];
+
+ buildInputs = [
+ curl
+ tzdata
+ # ] ++ lib.optionals stdenv.isDarwin [
+ # Foundation
+ ];
+
+ nativeCheckInputs = [
+ gdb
+ ] ++ lib.optionals (lib.versionOlder version "2.089.0") [
+ unzip
+ ];
+
+ buildFlags = [
+ "BUILD=release"
+ "ENABLE_RELEASE=1"
+ "PIC=1"
+ ];
+
+ # Build and install are based on http://wiki.dlang.org/Building_DMD
+ buildPhase = ''
+ runHook preBuild
+
+ export buildJobs=$NIX_BUILD_CORES
+ if [ -z $enableParallelBuilding ]; then
+ buildJobs=1
+ fi
+
+ ${dmd_bin}/rdmd dmd/compiler/src/build.d -j$buildJobs HOST_DMD=${dmd_bin}/dmd $buildFlags
+ make -C dmd/druntime -f posix.mak DMD=${pathToDmd} $buildFlags -j$buildJobs
+ echo ${tzdata}/share/zoneinfo/ > TZDatabaseDirFile
+ echo ${lib.getLib curl}/lib/libcurl${stdenv.hostPlatform.extensions.sharedLibrary} > LibcurlPathFile
+ make -C phobos -f posix.mak $buildFlags -j$buildJobs DMD=${pathToDmd} DFLAGS="-version=TZDatabaseDir -version=LibcurlPath -J$PWD"
+
+ runHook postBuild
+ '';
+
+ doCheck = true;
+
+ checkFlags = buildFlags;
+
+ # many tests are disbled because they are failing
+
+ # NOTE: Purity check is disabled for checkPhase because it doesn't fare well
+ # with the DMD linker. See https://github.com/NixOS/nixpkgs/issues/97420
+ checkPhase = ''
+ runHook preCheck
+
+ export checkJobs=$NIX_BUILD_CORES
+ if [ -z $enableParallelChecking ]; then
+ checkJobs=1
+ fi
+
+ NIX_ENFORCE_PURITY= \
+ make -C dmd/compiler/test $checkFlags CC=$CXX SHELL=$SHELL -j$checkJobs N=$checkJobs
+
+ NIX_ENFORCE_PURITY= \
+ make -C phobos -f posix.mak unittest $checkFlags -j$checkJobs DFLAGS="-version=TZDatabaseDir -version=LibcurlPath -J$PWD"
+
+ runHook postCheck
+ '';
+
+ installPhase = ''
+ runHook preInstall
+
+ install -Dm755 ${pathToDmd} $out/bin/dmd
+
+ installManPage dmd/docs/man/man*/*
+
+ mkdir -p $out/include/dmd
+ cp -r {dmd/druntime/import/*,phobos/{std,etc}} $out/include/dmd/
+
+ mkdir $out/lib
+ cp phobos/generated/${osname}/release/${bits}/libphobos2.* $out/lib/
+
+ wrapProgram $out/bin/dmd \
+ --prefix PATH ":" "${targetPackages.stdenv.cc}/bin" \
+ --set-default CC "${targetPackages.stdenv.cc}/bin/cc"
+
+ substitute ${dmdConfFile} "$out/bin/dmd.conf" --subst-var out
+
+ runHook postInstall
+ '';
+
+ preFixup = ''
+ find $out/bin -type f -exec ${removeReferencesTo}/bin/remove-references-to -t ${dmd_bin}/dmd '{}' +
+ '';
+
+ disallowedReferences = [ dmdBootstrap ];
+
+ meta = with lib; {
+ description = "Official reference compiler for the D language";
+ homepage = "https://dlang.org/";
+ # Everything is now Boost licensed, even the backend.
+ # https://github.com/dlang/dmd/pull/6680
+ license = licenses.boost;
+ maintainers = with maintainers; [ lionello dukc jtbx ];
+ platforms = [ "x86_64-linux" "i686-linux" "x86_64-darwin" ];
+ };
+}
diff --git a/nix-overlays/dtools/default.nix b/nix-overlays/dtools/default.nix
new file mode 100644
index 0000000..d605e4d
--- /dev/null
+++ b/nix-overlays/dtools/default.nix
@@ -0,0 +1,51 @@
+{ stdenv, lib, fetchFromGitHub, fetchpatch, ldc, curl, gnumake42 }:
+
+stdenv.mkDerivation rec {
+ pname = "dtools";
+ version = "2.103.1";
+
+ src = fetchFromGitHub {
+ owner = "dlang";
+ repo = "tools";
+ rev = "v${version}";
+ sha256 = "sha256-XM4gUxcarQCOBR8W/o0iWAI54PyLDkH6CsDce22Cnu4=";
+ name = "dtools";
+ };
+
+ patches = [
+ (fetchpatch {
+ # part of https://github.com/dlang/tools/pull/441
+ url = "https://github.com/dlang/tools/commit/6c6a042d1b08e3ec1790bd07a7f69424625ee866.patch"; # Fix LDC arm64 build
+ sha256 = "sha256-x6EclTYN1Y5FG57KLhbBK0BZicSYcZoWO7MTVcP4T18=";
+ })
+ ];
+
+ nativeBuildInputs = [ ldc gnumake42 ]; # fails with make 4.4
+ buildInputs = [ curl ];
+
+ makeCmd = ''
+ make -f posix.mak all DMD_DIR=dmd DMD=${ldc.out}/bin/ldmd2 CC=${stdenv.cc}/bin/cc
+ '';
+
+ buildPhase = ''
+ $makeCmd
+ '';
+
+ doCheck = true;
+
+ checkPhase = ''
+ $makeCmd test_rdmd
+ '';
+
+ installPhase = ''
+ $makeCmd INSTALL_DIR=$out install
+ '';
+
+ meta = with lib; {
+ description = "Ancillary tools for the D programming language compiler";
+ homepage = "https://github.com/dlang/tools";
+ license = lib.licenses.boost;
+ maintainers = with maintainers; [ ThomasMader ];
+ platforms = lib.platforms.unix;
+ };
+}
diff --git a/nix-overlays/dub/default.nix b/nix-overlays/dub/default.nix
new file mode 100644
index 0000000..819a5e5
--- /dev/null
+++ b/nix-overlays/dub/default.nix
@@ -0,0 +1,86 @@
+{ lib, stdenv, fetchFromGitHub, curl, libevent, rsync, ldc, dcompiler ? ldc }:
+
+assert dcompiler != null;
+
+stdenv.mkDerivation rec {
+ pname = "dub";
+ version = "1.36.0";
+
+ enableParallelBuilding = true;
+
+ src = fetchFromGitHub {
+ owner = "dlang";
+ repo = "dub";
+ rev = "v${version}";
+ sha256 = "sha256-S8pls9zxbGAQTwqYf4bDT2q7Ow12S8bBsJE5UmsACBs=";
+ };
+
+ #postUnpack = ''
+ # patchShebangs .
+ #'';
+
+ dubvar = "\\$DUB";
+ postPatch = ''
+ patchShebangs test
+
+ # Can be removed with https://github.com/dlang/dub/pull/1368
+ substituteInPlace test/fetchzip.sh \
+ --replace "dub remove" "\"${dubvar}\" remove"
+ '';
+
+ nativeBuildInputs = [ dcompiler libevent rsync ];
+ buildInputs = [ curl ];
+
+ buildPhase = ''
+ for DC_ in dmd ldmd2 gdmd; do
+ echo "... check for D compiler $DC_ ..."
+ export DC=$(type -P $DC_ || echo "")
+ if [ ! "$DC" == "" ]; then
+ break
+ fi
+ done
+ if [ "$DC" == "" ]; then
+ exit "Error: could not find D compiler"
+ fi
+ echo "$DC_ found and used as D compiler in buildPhase for $pname"
+ $DC ./build.d
+ ./build
+ '';
+
+ doCheck = !stdenv.isDarwin;
+
+ checkPhase = ''
+ export DUB=$NIX_BUILD_TOP/source/bin/dub
+ export PATH=$PATH:$NIX_BUILD_TOP/source/bin/
+ #export DC=${dcompiler.out}/bin/${if dcompiler.pname=="ldc" then "ldc2" else dcompiler.pname}
+ if [ "$DC" == "" ]; then
+ exit "Error: could not find D compiler"
+ fi
+ echo "DC out --> $DC"
+ export HOME=$TMP
+
+ rm -rf test/issue502-root-import
+ rm -rf test/dpath-variable
+ #rm test/dpath-variable.sh
+ rm -rf test/git-dependency
+ rm -rf test/use-c-sources # added to build v1.33.0
+ rm -rf test/pr2642-cache-db # added to build v1.34.0
+ rm -rf test/pr2644-describe-artifact-path # added to build v1.36.0
+ rm -rf test/pr2647-build-deep # added to build v1.36.0
+
+ ./test/run-unittest.sh
+ '';
+
+ installPhase = ''
+ mkdir -p $out/bin
+ cp bin/dub $out/bin
+ '';
+
+ meta = with lib; {
+ description = "Package and build manager for D applications and libraries";
+ homepage = "https://code.dlang.org/";
+ license = licenses.mit;
+ maintainers = with maintainers; [ jtbx ];
+ platforms = [ "x86_64-linux" "i686-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin" ];
+ };
+}
diff --git a/nix-overlays/ldc/binary.nix b/nix-overlays/ldc/binary.nix
new file mode 100644
index 0000000..ca7fb4f
--- /dev/null
+++ b/nix-overlays/ldc/binary.nix
@@ -0,0 +1,43 @@
+{ lib, stdenv, fetchurl, curl, tzdata, autoPatchelfHook, fixDarwinDylibNames, libxml2
+, version, hashes }:
+
+let
+ inherit (stdenv) hostPlatform;
+ OS = if hostPlatform.isDarwin then "osx" else hostPlatform.parsed.kernel.name;
+ ARCH = if hostPlatform.isDarwin && hostPlatform.isAarch64 then "arm64" else hostPlatform.parsed.cpu.name;
+in stdenv.mkDerivation {
+ pname = "ldc-bootstrap";
+ inherit version;
+
+ src = fetchurl rec {
+ name = "ldc2-${version}-${OS}-${ARCH}.tar.xz";
+ url = "https://github.com/ldc-developers/ldc/releases/download/v${version}/${name}";
+ sha256 = hashes."${OS}-${ARCH}" or (throw "missing bootstrap sha256 for ${OS}-${ARCH}");
+ };
+
+ dontConfigure = true;
+ dontBuild = true;
+
+ nativeBuildInputs = lib.optionals hostPlatform.isLinux [
+ autoPatchelfHook
+ ] ++ lib.optional hostPlatform.isDarwin fixDarwinDylibNames;
+
+ buildInputs = lib.optionals stdenv.hostPlatform.isLinux [ libxml2 stdenv.cc.cc ];
+
+ propagatedBuildInputs = [ curl tzdata ];
+
+ installPhase = ''
+ mkdir -p $out
+
+ mv bin etc import lib LICENSE README $out/
+ '';
+
+ meta = with lib; {
+ description = "The LLVM-based D Compiler";
+ homepage = "https://github.com/ldc-developers/ldc";
+ # from https://github.com/ldc-developers/ldc/blob/master/LICENSE
+ license = with licenses; [ bsd3 boost mit ncsa gpl2Plus ];
+ maintainers = with maintainers; [ lionello ];
+ platforms = [ "x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin" ];
+ };
+}
diff --git a/nix-overlays/ldc/bootstrap.nix b/nix-overlays/ldc/bootstrap.nix
new file mode 100644
index 0000000..7724cbc
--- /dev/null
+++ b/nix-overlays/ldc/bootstrap.nix
@@ -0,0 +1,11 @@
+{ callPackage }:
+callPackage ./binary.nix {
+ version = "1.25.0";
+ hashes = {
+ # Get these from `nix-prefetch-url https://github.com/ldc-developers/ldc/releases/download/v1.19.0/ldc2-1.19.0-osx-x86_64.tar.xz` etc..
+ osx-x86_64 = "sha256-6iKnbS+oalLKmyS8qYD/wS21b7+O+VgsWG2iT4PrWPU=";
+ linux-x86_64 = "sha256-sfg47RdlsIpryc3iZvE17OtLweh3Zw6DeuNJYgpuH+o=";
+ linux-aarch64 = "sha256-UDZ43x4flSo+SfsPeE8juZO2Wtk2ZzwySk0ADHnvJBI=";
+ osx-arm64 = "sha256-O/x0vy0wwQFaDc4uWSeMhx+chJKqbQb6e5QNYf+7DCw=";
+ };
+}
diff --git a/nix-overlays/ldc/default.nix b/nix-overlays/ldc/default.nix
new file mode 100644
index 0000000..2e194e4
--- /dev/null
+++ b/nix-overlays/ldc/default.nix
@@ -0,0 +1,4 @@
+import ./generic.nix {
+ version = "1.37.0";
+ sha256 = "sha256-UOgK48Q2yQY3wsPUDzktwotyH3qrOh48o79PnCjboGQ=";
+}
diff --git a/nix-overlays/ldc/generic.nix b/nix-overlays/ldc/generic.nix
new file mode 100644
index 0000000..2fd779a
--- /dev/null
+++ b/nix-overlays/ldc/generic.nix
@@ -0,0 +1,136 @@
+{ version, sha256 }:
+{ lib, stdenv, fetchurl, cmake, ninja, llvm_17, curl, tzdata
+, libconfig, lit, gdb, unzip, darwin, bash
+, callPackage, makeWrapper, runCommand, targetPackages
+, ldcBootstrap ? callPackage ./bootstrap.nix { }
+}:
+
+let
+ pathConfig = runCommand "ldc-lib-paths" {} ''
+ mkdir $out
+ echo ${tzdata}/share/zoneinfo/ > $out/TZDatabaseDirFile
+ echo ${curl.out}/lib/libcurl${stdenv.hostPlatform.extensions.sharedLibrary} > $out/LibcurlPathFile
+ '';
+
+in
+
+stdenv.mkDerivation rec {
+ pname = "ldc";
+ inherit version;
+
+ src = fetchurl {
+ url = "https://github.com/ldc-developers/ldc/releases/download/v${version}/ldc-${version}-src.tar.gz";
+ inherit sha256;
+ };
+
+ # https://issues.dlang.org/show_bug.cgi?id=19553
+ hardeningDisable = [ "fortify" ];
+
+ postUnpack = ''
+ patchShebangs .
+ ''
+ + ''
+ rm ldc-${version}-src/tests/dmd/fail_compilation/mixin_gc.d
+ rm ldc-${version}-src/tests/dmd/runnable/xtest46_gc.d
+ rm ldc-${version}-src/tests/dmd/runnable/testptrref_gc.d
+
+ # test depends on current year
+ rm ldc-${version}-src/tests/dmd/compilable/ddocYear.d
+ ''
+ + lib.optionalString stdenv.hostPlatform.isDarwin ''
+ # https://github.com/NixOS/nixpkgs/issues/34817
+ rm -r ldc-${version}-src/tests/plugins/addFuncEntryCall
+ '';
+
+ postPatch = ''
+ # Setting SHELL=$SHELL when dmd testsuite is run doesn't work on Linux somehow
+ #substituteInPlace tests/dmd/Makefile --replace "SHELL=/bin/bash" "SHELL=${bash}/bin/bash"
+ ''
+ + lib.optionalString stdenv.hostPlatform.isLinux ''
+ substituteInPlace runtime/phobos/std/socket.d --replace "assert(ih.addrList[0] == 0x7F_00_00_01);" ""
+ ''
+ + lib.optionalString stdenv.hostPlatform.isDarwin ''
+ substituteInPlace runtime/phobos/std/socket.d --replace "foreach (name; names)" "names = []; foreach (name; names)"
+ '';
+
+ nativeBuildInputs = [
+ cmake ldcBootstrap lit lit.python llvm_17.dev makeWrapper ninja unzip
+ ]
+ ++ lib.optionals stdenv.hostPlatform.isDarwin [
+ darwin.apple_sdk.frameworks.Foundation
+ ]
+ ++ lib.optionals (!stdenv.hostPlatform.isDarwin) [
+ # https://github.com/NixOS/nixpkgs/pull/36378#issuecomment-385034818
+ gdb
+ ];
+
+ buildInputs = [ curl tzdata ];
+
+ cmakeFlags = [
+ "-DD_FLAGS=-d-version=TZDatabaseDir;-d-version=LibcurlPath;-J${pathConfig}"
+ ];
+
+ postConfigure = ''
+ export DMD=$PWD/bin/ldmd2
+ '';
+
+ makeFlags = [ "DMD=$DMD" ];
+
+ fixNames = lib.optionalString stdenv.hostPlatform.isDarwin ''
+ fixDarwinDylibNames() {
+ local flags=()
+
+ for fn in "$@"; do
+ flags+=(-change "$(basename "$fn")" "$fn")
+ done
+
+ for fn in "$@"; do
+ if [ -L "$fn" ]; then continue; fi
+ echo "$fn: fixing dylib"
+ install_name_tool -id "$fn" "''${flags[@]}" "$fn"
+ done
+ }
+
+ fixDarwinDylibNames $(find "$(pwd)/lib" -name "*.dylib")
+ export DYLD_LIBRARY_PATH=$(pwd)/lib
+ '';
+
+ # https://github.com/ldc-developers/ldc/issues/2497#issuecomment-459633746
+ additionalExceptions = lib.optionalString stdenv.hostPlatform.isDarwin
+ "|druntime-test-shared";
+
+ checkPhase = ''
+ # Build default lib test runners
+ ninja -j$NIX_BUILD_CORES all-test-runners
+
+ ${fixNames}
+
+ # Run dmd testsuite
+ export DMD_TESTSUITE_MAKE_ARGS="-j$NIX_BUILD_CORES DMD=$DMD"
+ ctest -V -R "dmd-testsuite"
+
+ # Build and run LDC D unittests.
+ ctest --output-on-failure -R "ldc2-unittest"
+
+ # Run LIT testsuite.
+ ctest -V -R "lit-tests"
+
+ # Run default lib unittests
+ ctest -j$NIX_BUILD_CORES --output-on-failure -E "ldc2-unittest|lit-tests|dmd-testsuite${additionalExceptions}"
+ '';
+
+ postInstall = ''
+ wrapProgram $out/bin/ldc2 \
+ --prefix PATH ":" "${targetPackages.stdenv.cc}/bin" \
+ --set-default CC "${targetPackages.stdenv.cc}/bin/cc"
+ '';
+
+ meta = with lib; {
+ description = "The LLVM-based D compiler";
+ homepage = "https://github.com/ldc-developers/ldc";
+ # from https://github.com/ldc-developers/ldc/blob/master/LICENSE
+ license = with licenses; [ bsd3 boost mit ncsa gpl2Plus ];
+ maintainers = with maintainers; [ lionello jtbx ];
+ platforms = [ "x86_64-linux" "i686-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin" ];
+ };
+}
diff --git a/nixDevEnv.sh b/nixDevEnv.sh
new file mode 100644
index 0000000..640d07e
--- /dev/null
+++ b/nixDevEnv.sh
@@ -0,0 +1,3 @@
+if [ -f .envrc ]; then
+ source_env_if_exists .envrc || source .envrc
+fi
diff --git a/shell.nix b/shell.nix
new file mode 100755
index 0000000..b9015da
--- /dev/null
+++ b/shell.nix
@@ -0,0 +1,44 @@
+#!/usr/bin/env -S nix-shell --pure
+#!nix-shell -i bash
+{pkgs-nix ? import <nixpkgs> {}}:
+with pkgs-nix;
+ mkShell {
+ buildInputs = [
+ # ❯❯❯ nix_related
+ #nix
+ direnv
+ nixVersions.unstable
+ nix-prefetch-git
+ validatePkgConfig
+ nix-output-monitor
+ #nix-tree
+ #nvd
+ jq #gx
+ #alejandra
+ git
+ # ❯❯❯ dev
+ gnumake
+ ps
+ # ❯❯❯ d_build_related
+ # ❯❯ compiler
+ #dmd
+ #ldc
+ #rund
+ # ❯❯ package manager
+ #dub
+ # ❯❯ linker
+ #lld
+ #mold
+ # ❯❯ builder
+ #ninja
+ #meson
+ # ❯❯ tools
+ #dub
+ #dtools
+ # ❯❯❯ test
+ #tilix
+ #gtkd
+ ];
+ shellHook = ''
+ '';
+ }
generated by cgit v1.2.3 (git 2.25.1) at 2024-11-22 06:14:29 +0000