path: root/src/doc_reform/output/paths_output.d

/++
  default settings
+/
module doc_reform.output.paths_output;
import std.array,
  std.path,
  std.regex,
  std.stdio;
import doc_reform.meta.rgx;
template DocReformOutPaths() {
  auto DocReformOutPaths(Po,Lng)(
    Po  output_pth_root,
    Lng lng,
  ) {
    struct _PathsStruct {
      string output_root() {
        return (output_pth_root.length > 0)
        ? output_pth_root
        : "sisugen";
      }
      string output_base() {
        return asNormalizedPath(output_root.chainPath(lng)).array;
      }
    }
    return _PathsStruct();
  }
}
template DocReformOutPathSQLite() {
  auto DocReformOutPathSQLite(Po)(
    Po  output_pth_root,
  ) {
    struct _PathsStruct {
      string output_root() {
        return (output_pth_root.length > 0)
        ? output_pth_root
        : "sisugen";
      }
      string output_base() {
        return asNormalizedPath(output_root).array;
      }
    }
    return _PathsStruct();
  }
}
template DocReformOutPathsFnPd() {
  /+ TODO stuff to work out here +/
  auto DocReformOutPathsFnPd(Fn,Pn)(
    Fn  fn_src_pth,
    Pn  pod_name
  ) {
    struct _PathsStruct {
      string base_filename() {
        return fn_src_pth.baseName.stripExtension;
      }
      string base_pod_and_filename() { // TODO
        /+
          - if pod,
            - pod_name
            - file_name
            - if pod_name == file_name
              - file_name
            - else if pod_name != file_name
              - pod_name.file_name
        +/
        string _fn_src = fn_src_pth.baseName.stripExtension;
        string _output_base_name;
        if (!(pod_name.empty)) {
          if (pod_name == _fn_src) {
            _output_base_name = _fn_src;
          } else {
            _output_base_name = pod_name ~ "." ~ _fn_src;
          }
        } else {
          _output_base_name = _fn_src;
        }
        return _output_base_name;
      }
    }
    return _PathsStruct();
  }
}
template DocReformPathsUrl() {
  import std.format;
  mixin DocReformRgxInit;
  static auto rgx = Rgx();
  auto DocReformPathsUrl(M)(M doc_matters) {
    struct _UrlPathsStruct {
      string doc_root() {
        string _doc_root = (doc_matters.conf_make_meta.conf.webserv_url_doc_path.length > 0)
        ? doc_matters.conf_make_meta.conf.webserv_url_doc_root
        : "file://" ~ doc_matters.output_path;
        return _doc_root;
      }
      string html_seg(string html_segname, string obj_id) { // TODO bespoke for sqlite
        string _url = format(q"┋%s/%s/html/%s/%s.html#%s┋",
          doc_root,
          doc_matters.src.language,
          doc_matters.src.filename_base,
          html_segname,
          obj_id
        );
        if (html_segname.empty || obj_id.empty) {
          if (
            doc_matters.opt.action.debug_do
            && doc_matters.opt.action.verbose
          ) {
            writeln("sqlite object missing segname or object id: ", _url);
          }
          _url = "";
        }
        return _url;
      }
    }
    return _UrlPathsStruct();
  }
}
template DocReformPathsHTML() {
  mixin DocReformRgxInit;
  static auto rgx = Rgx();
  auto DocReformPathsHTML(Po,Lng)(
    Po  output_pth_root,
    Lng lng,
  ) {
    auto out_pth = DocReformOutPaths!()(output_pth_root, lng);
    string base_dir = "html";
    string suffix = ".html";
    struct _PathsStruct {
      string base_filename(string fn_src) {
        return fn_src.baseName.stripExtension;
      }
      string base() {
        return asNormalizedPath((out_pth.output_base).chainPath(base_dir)).array;
      }
      string image() {
        return asNormalizedPath((out_pth.output_root).chainPath("image")).array;
      }
      string css() {
        return asNormalizedPath((out_pth.output_root).chainPath("css")).array;
      }
      string fn_seg_css() {
        return asNormalizedPath(css.chainPath("html_seg.css")).array;
      }
      string fn_scroll_css() {
        return asNormalizedPath(css.chainPath("html_scroll.css")).array;
      }
      string seg(string fn_src) {
        return asNormalizedPath(base.chainPath(base_filename(fn_src))).array;
      }
      string fn_scroll(string fn_src) {
        return asNormalizedPath(base.chainPath(base_filename(fn_src) ~ suffix)).array;
      }
      string fn_seg(string fn_src, string seg_filename) {
        return asNormalizedPath(seg(fn_src).chainPath(seg_filename ~ suffix)).array;
      }
      string tail_seg(string fn_src) {
        return lng ~ "/html/" ~ base_filename(fn_src);
      }
      string tail_fn_scroll(string fn_src) {
        return lng ~ "/html/" ~ base_filename(fn_src) ~ suffix;
      }
      string tail_fn_seg(string fn_src, string seg_filename) {
        return lng ~ "/html/" ~ seg(fn_src) ~ "/" ~ seg_filename ~ suffix;
      }
    }
    return _PathsStruct();
  }
}
template DocReformPathsEPUB() {
  mixin DocReformRgxInit;
  static auto rgx = Rgx();
  auto DocReformPathsEPUB(Po,Lng)(
    Po  output_pth_root,
    Lng lng,
  ) {
    auto out_pth = DocReformOutPaths!()( output_pth_root, lng);
    string base_dir = "epub";
    struct _PathsStruct {
      string base() {
        return asNormalizedPath((out_pth.output_base).chainPath(base_dir)).array;
      }
      string base_filename(string fn_src) {
        return fn_src.baseName.stripExtension;
      }
      string epub_file(string fn_src) {
        return asNormalizedPath(base.chainPath(base_filename(fn_src) ~ ".epub")).array;
      }
      string dirtop() {
        return "".chainPath("").array;
      }
      string doc_meta_inf(string fn_src) {
        return asNormalizedPath(dirtop.chainPath("META-INF")).array;
      }
      string doc_oebps(string fn_src) {
        return asNormalizedPath(dirtop.chainPath("OEBPS")).array;
      }
      string doc_oebps_css(string fn_src) {
        return asNormalizedPath(doc_oebps(fn_src).chainPath("css")).array;
      }
      string doc_oebps_image(string fn_src) {
        return asNormalizedPath(doc_oebps(fn_src).chainPath("image")).array;
      }
      string fn_mimetypes(string fn_src) {
        return asNormalizedPath(dirtop.chainPath("mimetypes")).array;
      }
      string fn_dmi_container_xml(string fn_src) {
        return asNormalizedPath(doc_meta_inf(fn_src).chainPath("container.xml")).array;
      }
      string fn_oebps_toc_nav_xhtml(string fn_src) {
        return asNormalizedPath(doc_oebps(fn_src).chainPath("toc_nav.xhtml")).array;
      }
      string fn_oebps_toc_ncx(string fn_src) {
        return asNormalizedPath(doc_oebps(fn_src).chainPath("toc.ncx")).array;
      }
      string fn_oebps_content_opf(string fn_src) {
        return asNormalizedPath(doc_oebps(fn_src).chainPath("content.opf")).array;
      }
      string fn_oebps_content_xhtml(string fn_src, string seg_filename) {
        return asNormalizedPath(doc_oebps(fn_src).chainPath(seg_filename ~ ".xhtml")).array;
      }
      string fn_oebps_css(string fn_src) {
        return asNormalizedPath(doc_oebps_css(fn_src).chainPath("epub.css")).array;
      }
      /+ debug +/
      string dbg_docdir(string fn_src) {
        return base.chainPath(base_filename(fn_src)).array;
      }
      string dbg_docdir_oebps(string fn_src) {
        return dbg_docdir(fn_src).chainPath("OEBPS").array;
      }
      string dbg_doc_meta_inf(string fn_src) {
        return dbg_docdir(fn_src).chainPath("META-INF").array;
      }
      string dbg_doc_oebps(string fn_src) {
        return dbg_docdir(fn_src).chainPath("OEBPS").array;
      }
      string dbg_doc_oebps_css(string fn_src) {
        return dbg_doc_oebps(fn_src).chainPath("css").array;
      }
      string dbg_doc_oebps_image(string fn_src) {
        return dbg_doc_oebps(fn_src).chainPath("image").array;
      }
      string dbg_fn_mimetypes(string fn_src) {
        return dbg_docdir(fn_src).chainPath("mimetypes").array;
      }
      string dbg_fn_dmi_container_xml(string fn_src) {
        return dbg_doc_meta_inf(fn_src).chainPath("container.xml").array;
      }
      string dbg_fn_oebps_toc_nav_xhtml(string fn_src) {
        return dbg_docdir_oebps(fn_src).chainPath("toc_nav.xhtml").array;
      }
      string dbg_fn_oebps_toc_ncx(string fn_src) {
        return dbg_docdir_oebps(fn_src).chainPath("toc.ncx").array;
      }
      string dbg_fn_oebps_content_opf(string fn_src) {
        return dbg_docdir_oebps(fn_src).chainPath("content.opf").array;
      }
      string dbg_fn_oebps_content_xhtml(string fn_src, string seg_filename) {
        return dbg_docdir_oebps(fn_src).chainPath(seg_filename ~ ".xhtml").array;
      }
      string dbg_fn_oebps_css(string fn_src) {
        return dbg_doc_oebps_css(fn_src).chainPath("epub.css").array;
      }
    }
    return _PathsStruct();
  }
}
template DocReformPathsSQLiteDiscrete() {
  mixin DocReformRgxInit;
  static auto rgx = Rgx();
  auto DocReformPathsSQLiteDiscrete(Po,Lng)(
    Po  output_pth_root,
    Lng lng,
  ) {
    struct _PathsStruct {
      string base_filename(string fn_src) {
        return fn_src.baseName.stripExtension;
      }
      string base() {
        auto out_pth = DocReformOutPaths!()(output_pth_root, lng);
        string base_dir = "sqlite";
        return asNormalizedPath((out_pth.output_base).chainPath(base_dir)).array;
      }
      string seg(string fn_src) {
        return asNormalizedPath(base.chainPath(base_filename(fn_src))).array;
      }
      string sqlite_file(string fn_src) {
        return asNormalizedPath(base.chainPath(base_filename(fn_src) ~ ".sql.db")).array;
      }
    }
    return _PathsStruct();
  }
}
template DocReformPathsSQLite() {
  mixin DocReformRgxInit;
  static auto rgx = Rgx();
  auto DocReformPathsSQLite(DbN, Po)(
    DbN db_name,
    Po  output_pth_root,
  ) {
    struct _PathsStruct {
      string base_filename(string fn_src) {
        return fn_src.baseName.stripExtension;
      }
      string base() {
        auto out_pth = DocReformOutPathSQLite!()(output_pth_root); // decide whether to have separate files for each language
        string base_dir = "sqlite";
        return asNormalizedPath((out_pth.output_root).chainPath(base_dir)).array;
      }
      string sqlite_file() {
        return asNormalizedPath(base.chainPath(base_filename(db_name) ~ ".sql.db")).array;
      }
    }
    return _PathsStruct();
  }
}